apoc.agg.maxItems
Function

Details
Syntax	`apoc.agg.maxItems(item, value [, groupLimit ])`
Description	Returns a `MAP` `{items: LIST<ANY>, value: ANY}` where the `value` key is the maximum value present, and `items` represent all items with the same value. The size of the list of items can be limited to a given max size.
Arguments	Name	Type	Description
	`item`	`ANY`	A value to be aggregated.
	`value`	`ANY`	The value from which the max is selected.
	`groupLimit`	`INTEGER`	The limit on the number of items returned. The default is: `-1`.
Returns	`ANY`

Usage examples

The examples in this section are based on the following sample graph of people and their dates of birth:

CREATE (:Person {name: "Christopher Nolan", dateOfBirth: date("1970-07-30")});
CREATE (:Person {name: "Tom Cruise", dateOfBirth: date("1962-07-03")});
CREATE (:Person {name: "Nicole Kidman", dateOfBirth: date("1967-06-20")});
CREATE (:Person {name: "Matt Damon", dateOfBirth: date("1970-10-08")});
CREATE (:Person {name: "Jennifer Connelly", dateOfBirth: date("1970-12-12")});

You can collect the people that have the maximal year of birth by running the following query:

MATCH (p:Person)
WITH apoc.agg.maxItems(p, p.dateOfBirth.year) AS maxItems
RETURN maxItems.value AS value, maxItems.items AS items;

Results
value	items
1970	[(:Person {name: "Christopher Nolan", dateOfBirth: 1970-07-30}), (:Person {name: "Matt Damon", dateOfBirth: 1970-10-08}), (:Person {name: "Jennifer Connelly", dateOfBirth: 1970-12-12})]

You can set the groupLimit (3rd parameter) to set a limit on the number of items returned:

MATCH (p:Person)
WITH apoc.agg.maxItems(p, p.dateOfBirth.year, 2) AS maxItems
RETURN maxItems.value AS value, maxItems.items AS items;

Results
value	items
1970	[(:Person {name: "Christopher Nolan", dateOfBirth: 1970-07-30}), (:Person {name: "Matt Damon", dateOfBirth: 1970-10-08})]