9.6.1. The Adamic Adar algorithm

This section describes the Adamic Adar algorithm in the Neo4j Labs Graph Algorithms library.

Adamic Adar is a measure used to compute the closeness of nodes based on their shared neighbors.

The Adamic Adar algorithm was developed by the Neo4j Labs team and is not officially supported.

This section includes:

9.6.1.1. History and explanation

The Adamic Adar algorithm was introduced in 2003 by Lada Adamic and Eytan Adar to predict links in a social network. It is computed using the following formula:

adamic adar

where N(u) is the set of nodes adjacent to u.

A value of 0 indicates that two nodes are not close, while higher values indicate nodes are closer.

The library contains a function to calculate closeness between two nodes.

9.6.1.2. Adamic Adar algorithm sample

The following will create a sample graph: 

MERGE (zhen:Person {name: "Zhen"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (michael:Person {name: "Michael"})
MERGE (arya:Person {name: "Arya"})
MERGE (karin:Person {name: "Karin"})

MERGE (zhen)-[:FRIENDS]-(arya)
MERGE (zhen)-[:FRIENDS]-(praveena)
MERGE (praveena)-[:WORKS_WITH]-(karin)
MERGE (praveena)-[:FRIENDS]-(michael)
MERGE (michael)-[:WORKS_WITH]-(karin)
MERGE (arya)-[:FRIENDS]-(karin)

The following will return the Adamic Adar score for Michael and Karin: 

MATCH (p1:Person {name: 'Michael'})
MATCH (p2:Person {name: 'Karin'})
RETURN algo.linkprediction.adamicAdar(p1, p2) AS score

Table 9.157. Results
score

1.4426950408889634

We can also compute the score of a pair of nodes based on a specific relationship type.

The following will return the Adamic Adar score for Michael and Karin based only on the FRIENDS relationships: 

MATCH (p1:Person {name: 'Michael'})
MATCH (p2:Person {name: 'Karin'})
RETURN algo.linkprediction.adamicAdar(p1, p2, {relationshipQuery: "FRIENDS"}) AS score

Table 9.158. Results
score

0.0

9.6.1.3. Syntax

The following will run the algorithm and return the result: 

RETURN algo.linkprediction.adamicAdar(node1:Node, node2:Node, {
    relationshipQuery: null,
    direction: "BOTH"
})

Table 9.159. Parameters
Name Type Default Optional Description

node1

Node

null

no

A node

node2

Node

null

no

Another node

relationshipQuery

String

null

yes

The relationship type used to compute similarity between node1 and node2

direction

String

BOTH

yes

The direction of relationship type used to compute similarity between node1 and node2