Pharmaceutical Drugs and their Targets

Domain

A pharmaceutical portfolio is a collection of drug compounds, their respective indications, and their targets. A pharmaceutical company or drugstore organizes its pharmaceutical products into one or more portfolios. A drug portfolio thus contains multiple pharmaceuticals, with each pharmaceutical containing a link to one or more of its targets in the human body. This lends itself to be modeled as a graph. Each pharmaceutical and drug target can also have a distinct set of attributes which also fit nicely into the property graph model. Within the examples found in this use case, most drug targets happen to be G-protein coupled receptors (GPCRs), for which structures have only recently been solved in the last several years.

A drug can have one or more targets. A target can be targeted by one or more drugs. This is not a complete solution for all the drug portfolio use cases but provides a good starting point.

Figure 1. Domain Model

Setup

The sample data set uses a pharmaceutical portfolio.

CREATE (drugPortfolio:Portfolio{ name:'Pharmaceutical Portfolio' })

CREATE (drugs:Category { name:'Drugs' })
CREATE (drugs)-[:PARENT]->(drugPortfolio)

CREATE (antipsychotic_agents:Category { name:'Antipsychotic Agents' })
CREATE (antipsychotic_agents)-[:PARENT]->(drugs)
CREATE (antiparkinson_agents:Category { name:'Antiparkinson Agents' })
CREATE (antiparkinson_agents)-[:PARENT]->(drugs)
CREATE (antimigraine_agents:Category { name:'Antimigraine Agents' })
CREATE (antimigraine_agents)-[:PARENT]->(drugs)
CREATE (antidepressive_agents:Category { name:'Antidepressive Agents' })
CREATE (antidepressive_agents)-[:PARENT]->(drugs)
CREATE (antiallergic_agents:Category { name:'Antiallergic Agents' })
CREATE (antiallergic_agents)-[:PARENT]->(drugs)
CREATE (cns_stimulants:Category { name:'CNS Stimulants' })
CREATE (cns_stimulants)-[:PARENT]->(drugs)
CREATE (bronchodilator_agents:Category { name:'Bronchodilator Agents' })
CREATE (bronchodilator_agents)-[:PARENT]->(drugs)
CREATE (vasodilator:Category { name:'Vasodilator' })
CREATE (vasodilator)-[:PARENT]->(drugs)

CREATE (HUMAN_5HT1A:DrugTarget{ name:'5HT1A_HUMAN' })
CREATE (HUMAN_5HT1B:DrugTarget{ name:'5HT1B_HUMAN' })
CREATE (HUMAN_5HT2A:DrugTarget{ name:'5HT2A_HUMAN' })
CREATE (HUMAN_AA1R:DrugTarget{ name:'AA1R_HUMAN' })
CREATE (HUMAN_AA2AR:DrugTarget{ name:'AA2AR_HUMAN' })
CREATE (HUMAN_AA2BR:DrugTarget{ name:'AA2BR_HUMAN' })

CREATE (clozapine:Product { name:'Clozapine' })
CREATE (clozapine)-[:OF_TYPE]->(antipsychotic_agents)
CREATE (clozapine)-[:TARGETS]->(HUMAN_5HT1A)

CREATE (aripiprazole:Product { name:'Aripiprazole' })
CREATE (aripiprazole)-[:OF_TYPE]->(antipsychotic_agents)
CREATE (aripiprazole)-[:TARGETS]->(HUMAN_5HT1A)

CREATE (lisuride:Product { name:'Lisuride' })
CREATE (lisuride)-[:OF_TYPE]->(antiparkinson_agents)
CREATE (lisuride)-[:TARGETS]->(HUMAN_5HT1A)

CREATE (methysergide:Product { name:'Methysergide' })
CREATE (methysergide)-[:OF_TYPE]->(antimigraine_agents)
CREATE (methysergide)-[:TARGETS]->(HUMAN_5HT1A)

CREATE (almotriptan:Product { name:'Almotriptan' })
CREATE (almotriptan)-[:OF_TYPE]->(antimigraine_agents)
CREATE (almotriptan)-[:TARGETS]->(HUMAN_5HT1B)

CREATE (eletriptan:Product { name:'Eletriptan' })
CREATE (eletriptan)-[:OF_TYPE]->(antimigraine_agents)
CREATE (eletriptan)-[:TARGETS]->(HUMAN_5HT1B)

CREATE (ergotamine:Product { name:'Ergotamine' })
CREATE (ergotamine)-[:OF_TYPE]->(antimigraine_agents)
CREATE (ergotamine)-[:TARGETS]->(HUMAN_5HT1B)

CREATE (frovatriptan:Product { name:'Frovatriptan' })
CREATE (frovatriptan)-[:OF_TYPE]->(antimigraine_agents)
CREATE (frovatriptan)-[:TARGETS]->(HUMAN_5HT1B)

CREATE (naratriptan:Product { name:'Naratriptan' })
CREATE (naratriptan)-[:OF_TYPE]->(antimigraine_agents)
CREATE (naratriptan)-[:TARGETS]->(HUMAN_5HT1B)

CREATE (chlorprothixene:Product { name:'Chlorprothixene' })
CREATE (chlorprothixene)-[:OF_TYPE]->(antipsychotic_agents)
CREATE (chlorprothixene)-[:TARGETS]->(HUMAN_5HT2A)

CREATE (clozapine)-[:OF_TYPE]->(antipsychotic_agents)
CREATE (clozapine)-[:TARGETS]->(HUMAN_5HT2A)

CREATE (cyclobenzaprine:Product { name:'Cyclobenzaprine' })
CREATE (cyclobenzaprine)-[:OF_TYPE]->(antidepressive_agents)
CREATE (cyclobenzaprine)-[:TARGETS]->(HUMAN_5HT2A)

CREATE (cyproheptadine:Product { name:'Cyclobenzaprine' })
CREATE (cyproheptadine)-[:OF_TYPE]->(antiallergic_agents)
CREATE (cyproheptadine)-[:TARGETS]->(HUMAN_5HT2A)

CREATE (caffeine:Product { name:'Caffeine' })
CREATE (caffeine)-[:OF_TYPE]->(cns_stimulants)
CREATE (caffeine)-[:TARGETS]->(HUMAN_AA1R)
CREATE (caffeine)-[:TARGETS]->(HUMAN_AA2AR)

CREATE (theophylline:Product { name:'Theophylline' })
CREATE (theophylline)-[:OF_TYPE]->(bronchodilator_agents)
CREATE (theophylline)-[:TARGETS]->(HUMAN_AA1R)
CREATE (theophylline)-[:TARGETS]->(HUMAN_AA2AR)
CREATE (theophylline)-[:TARGETS]->(HUMAN_AA2BR)

CREATE (regadenoson:Product { name:'Regadenoson' })
CREATE (regadenoson)-[:OF_TYPE]->(vasodilator)
CREATE (regadenoson)-[:TARGETS]->(HUMAN_AA2AR)

Try other queries yourself!

Use Cases

All portfolios

MATCH (c:Portfolio)
RETURN c.name AS Portfolios

All categories by Depth

MATCH p=(cats:Category)-[:PARENT|PARENT*]->(cat:Portfolio)
RETURN LENGTH(p) AS Depth, COLLECT(cats.name) AS Categories
ORDER BY Depth ASC

All categories of a given depth

MATCH p=(cats:Category)-[:PARENT*]->(cat:Portfolio)
WHERE cat.name='Pharmaceutical Portfolio' AND length(p)=1
RETURN cats.name AS `Categories of Given Level`
ORDER BY cats.name

All sub-categories of a given category

MATCH (cats:Category)-[:PARENT]->(parentCat:Category)
MATCH (parentCat)-[:PARENT*]->(c:Portfolio)
RETURN parentCat.name AS Parent, COLLECT(cats.name) AS SubCategories

All parents and their child categories

MATCH (child:Category)-[:PARENT*]->(parent)
RETURN parent.name AS Parent, COLLECT(child.name) AS Children

All parent and their IMMEDIATE children

MATCH (child:Category)-[:PARENT]->(parent)
RETURN labels(parent), parent.name AS Parent, COLLECT(child.name) AS Children

Is this page helpful?

GraphGists