Analyzing the BuzzFeed TrumpWorld Dataset with Neo4j

Hey @neo4j please do this once again!!! #panamapapers #neo4j
https://t.co/B8pjxNKCyA

— sanchezcastro (@SCHZCAS) January 15, 2017

Now we are asking the public to use our data to find connections we may have missed, and to give us context we don’t currently understand. We hope you will help us — and the public — learn more about TrumpWorld and how this unprecedented array of businesses might affect public policy.

Digging into the TrumpWorld Dataset

WITH
'https://docs.google.com/spreadsheets/u/1/d/1Z5Vo5pbvxKJ5XpfALZXvCzW26Cl4we3OaN73K9Ae5Ss/export?format=csv&gid=634968401' AS url
LOAD CSV WITH HEADERS FROM url AS row
RETURN row.`Organization A`,row.`Organization B`,row.Connection, row.`Source(s)`
LIMIT 5

• (:Organization)-[:CONNECTED_TO]->(:Organization)
• (:Person)-[:INVOLVED_WITH]->(:Organization)
• (:Person)-[:RELATED_TO]->(:Person)

1. We get the data from the CSV file
2. Create or find (MERGE) the two nodes
3. Connect them with a relationship

Data Import

Data Constraints

CREATE CONSTRAINT ON (o:Organization) ASSERT o.name IS UNIQUE;
CREATE CONSTRAINT ON (p:Person) ASSERT p.name IS UNIQUE;

Connect Organizations with Other organizations from the 1st Tab

WITH 'https://docs.google.com/spreadsheets/u/1/d/1Z5Vo5pbvxKJ5XpfALZXvCzW26Cl4we3OaN73K9Ae5Ss/export?format=csv&gid=634968401' AS url
LOAD CSV WITH HEADERS FROM url AS row
MERGE (o1:Organization {name:row.`Organization A`})
MERGE (o2:Organization {name:row.`Organization B`})
CREATE (o1)-[con:CONNECTED_TO]->(o2)
SET con.connection=row.Connection, con.source=row.`Source(s)`

Connect People with Organizations from the 2nd Tab

WITH 'https://docs.google.com/spreadsheets/u/1/d/1Z5Vo5pbvxKJ5XpfALZXvCzW26Cl4we3OaN73K9Ae5Ss/export?format=csv&gid=1368567920' AS url
LOAD CSV WITH HEADERS FROM url AS row
MERGE (p:Person {name:row.Person})
MERGE (o:Organization {name:row.Organization})
CREATE (p)-[con:INVOLVED_WITH]->(o)
SET con.connection=row.Connection, con.source=row.`Source(s)`

Connect People with other People from the 3rd Tab

WITH 'https://docs.google.com/spreadsheets/u/1/d/1Z5Vo5pbvxKJ5XpfALZXvCzW26Cl4we3OaN73K9Ae5Ss/export?format=csv&gid=905294723' AS url
LOAD CSV WITH HEADERS FROM url AS row
MERGE (p1:Person {name:row.`Person A`})
MERGE (p2:Person {name:row.`Person B`})
CREATE (p2)-[con:RELATED_TO]->(p1)
SET con.connection=row.Connection, con.source=row.`Source(s)`

Import Results

Running Some Simple Graph Database Queries

Most-Connected Organizations

MATCH (o:Organization)-[r]-()
RETURN o.name, count(*), collect(distinct type(r)) AS types
ORDER BY count(*) DESC
LIMIT 5

╒═════════════════════════════════════╤═══════════╤═══════════════════════════════════╕
│"o.name"                          │"count(*)"│"types"                         │
╞═════════════════════════════════════╪═══════════╪═══════════════════════════════════╡
│"THRIVE CAPITAL"                  │86        │["CONNECTED_TO","INVOLVED_WITH"]│
├─────────────────────────────────────┼───────────┼───────────────────────────────────┤
│"40 WALL STREET LLC"              │41        │["INVOLVED_WITH","CONNECTED_TO"]│
├─────────────────────────────────────┼───────────┼───────────────────────────────────┤
│"DJT HOLDINGS LLC"                │36        │["INVOLVED_WITH","CONNECTED_TO"]│
├─────────────────────────────────────┼───────────┼───────────────────────────────────┤
│"KUSHNER COMPANIES"               │32        │["INVOLVED_WITH","CONNECTED_TO"]│
├─────────────────────────────────────┼───────────┼───────────────────────────────────┤
│"TRUMP HOTELS & CASINO RESORTS"   │28        │["INVOLVED_WITH","CONNECTED_TO"]│
└─────────────────────────────────────┴───────────┴───────────────────────────────────┘

The Second-Degree Kushner Network

MATCH network = (:Person {name:"JARED KUSHNER"})-[*..2]-()
RETURN network

Which Banks Are Involved with These Organizations and People?

MATCH (bank:Organization)--(other)
WHERE bank.name contains "BANK"
RETURN *

Donald Trump’s Connections to Vladimir Putin

MATCH (vp:Person {name:"VLADIMIR PUTIN"}),(dt:Person {name:"DONALD J. TRUMP"})
MATCH path = allShortestPaths( (vp)-[*]-(dt) )
RETURN path

Other Nominees of Trump’s Cabinet

MATCH (p:Person)-[con:RELATED_TO]->()
WHERE con.connection CONTAINS "Nominee"
RETURN p.name, con.connection
ORDER BY split(p.name," ")[-1] DESC LIMIT 5

Nominee Influence

MATCH (o:Organization)<-[:INVOLVED_WITH]-(p:Person)-[con:RELATED_TO]->()
WHERE con.connection CONTAINS "Nominee"
RETURN o,p

Fun Graph Query

match (p1:Person), (p2:Person) where id(p1) < id(p2)
match p = shortestPath((p1)-[*]-(p2))
return p1,p2,length(p) order by length(p) desc limit 20

╒══════════════════════════════╤═══════════════════════════╤═════════════╕
│"p1"                        │"p2"                    │"length(p)" │
╞══════════════════════════════╪═══════════════════════════╪═════════════╡
│{"name":"VICTOR HEGGELMAN"} │{"name":"ZHUO RAN"}      │10         │
├──────────────────────────────┼───────────────────────────┼─────────────┤
│{"name":"VICTOR HEGGELMAN"} │{"name":"CHRIS CHRISTIE"}│10         │
├──────────────────────────────┼───────────────────────────┼─────────────┤
│{"name":"TIM MOL"}          │{"name":"ZHUO RAN"}      │10         │
├──────────────────────────────┼───────────────────────────┼─────────────┤
│{"name":"ROMA DOWNEY"}      │{"name":"ZHUO RAN"}      │10         │
├──────────────────────────────┼───────────────────────────┼─────────────┤
│{"name":"CHRIS CHRISTIE"}   │{"name":"ROMA DOWNEY"}   │10         │
├──────────────────────────────┼───────────────────────────┼─────────────┤
│{"name":"LEV LEVIEV"}       │{"name":"JOSE GARCIA"}   │9          │
└──────────────────────────────┴───────────────────────────┴─────────────┘

MATCH (p1:Person {name:"LEV LEVIEV"}), (p2:Person {name:"ROMA DOWNEY"})
MATCH path = allShortestPaths((p1)-[*]-(p2))
RETURN path

Extending the TrumpWorld Graph

• Combine with related data from littlesis.org, "the involuntary registry of the 1%"
• Add FEC campaign financing information
• Add foundation detail data from citizenaudit.org
• Add people involved with the election campaign
• Add second-degree organizations related to the other people in the graph, not just Donald J. Trump
• Add more detailed information on the organizations and their setup (location, leadership, deals), e.g. by querying APIs like OpenCorporates or by integrating with the data from Aleph the OCCRP data portal