Additions, deprecations, removals, and compatibility

Cypher® is a language that is constantly evolving. New features are added to the language continuously, and occasionally, some features become deprecated and are subsequently removed. All changes to Cypher are introduced in Neo4j versions.

This section lists all of the features that have been removed, deprecated, added, or extended in different versions of Neo4j. Replacement syntax for deprecated and removed features are also indicated.

Neo4j 2026.02+ databases explicitly set Cypher 25 as their query language. Cypher 25 was introduced in Neo4j 2025.06 and can only be used on Neo4j 2025.06+ databases. Any new Cypher features introduced in Neo4j 2025.06 or later will be exclusively added to Cypher 25. Features removed in Cypher 25 are still available on Neo4j 2025.06+ databases either by prepending a query with CYPHER 5 or by having Cypher 5 as the default language for the database. For more information, see Select Cypher version.

Neo4j 2026.05

Updates

Feature Details

Updated

MATCH p = ANY SHORTEST ACYCLIC (a:A)-->+(b:!A)
RETURN p

Explicit path modes such as ACYCLIC can now be combined with restrictive path selectors, such as SHORTEST. For more information, see Patterns → Mixing restrictive path selectors and explicit path modes.

Updated

SHOW FUNCTIONS
YIELD name, signature
WITH name, collect(signature) AS signatures
FILTER size(signatures) > 1
RETURN name, signatures

Show indexes, constraints, current graph type, functions, procedures, settings, databases, and transactions, and terminate transactions can be combined with each other and general Cypher clauses in a single query. For more information, see SHOW → Composable SHOW commands. For SHOW DATABASES, all parts of the query must be allowed on the system database. For more information, see the Operations Manual → Show databases.

Updated

SHOW SETTINGS null
SHOW TRANSACTIONS null
TERMINATE TRANSACTIONS null
SHOW DATABASE $nullParam

Show settings, databases, and transactions, and terminate transactions treat null input the same as non-existent input. The show commands filter out the null input. Terminate transactions return a row about the transaction not being found.

For full information about these commands, see the following pages in the Operations Manual:

New

Feature Details

New

RETURN string.indexOf('hello', 'l');
RETURN string.join(['one', 'two'], ', ');
RETURN string.regexReplace("hello", "l.", "w");

Introduction of three new string-based Cypher functions: string.indexOf(), string.join(), and string.regexReplace().

Neo4j 2026.04

Deprecations

Feature Details

Deprecated

db.index.vector.queryNodes()
db.index.vector.queryRelationships()

Deprecated the two vector index procedures db.index.vector.queryNodes() and db.index.vector.queryRelationships() in favor of Cypher’s SEARCH clause.

New

Feature Details

New

FOR x IN [1, 2, 3]
RETURN x

The FOR clause (optional GQL feature GQ10) expands a list into rows using GQL conformant syntax: FOR variable IN expression.

New

MATCH (n:Person)
RETURN n IS LABELED Manager AS isManager

IS [NOT] LABELED predicate: tests a node or relationship against a label expression, equivalent to the existing colon form.

Neo4j 2026.03

New

Feature Details

New

MATCH p = ACYCLIC (start)--{,2}(end)
RETURN p

Introduction of the ACYCLIC keyword, which adds a further restriction to a pattern match which ensures that nodes cannot be repeated within a path (though they can still be repeated across paths to form equijoins.)

New

PROPERTY_EXISTS predicate

A new PROPERTY_EXISTS(element, propertyName) predicate had been added for testing whether a property exists on a node or relationship and is not NULL.

New

currentQueryProgress column for SHOW TRANSACTIONS

A new column currentQueryProgress has been added to the output table of SHOW TRANSACTIONS. See the Operations Manual → Show and terminate transactions for details.

Neo4j 2026.02

Updates

Feature Details

Updated

New databases now explicitly set Cyper 25 as their query language.

New self-managed installations and new Aura instances now explicitly set Cyper 25 as their query language. New self-managed deployments have the setting db.query.default_language=CYPHER_25 in their neo4j.conf file. Existing deployments retain their neo4j.conf file. Both can be adjusted via the setting db.query.default_language.

+ In Aura, Cypher 25 is the default for newly created organisations. The default query language attached to created databases is determined by the organisation setting "Default Cypher Version" and can be manually changed.

Updated

SHOW CONSTRAINTS YIELD name, enforcedLabel, classification

Introduced two new columns returned by SHOW CONSTRAINTS:

  • enforcedLabel: shows the implied labels belonging to a node element type, and the source and target node labels belonging to a relationship element type.

  • classification: shows the status of a constraint in a graph type.

For more information, see Constraints → Return columns and Graph types → Graph type elements in SHOW CONSTRAINTS.

Updated

SHOW [NODE] EXIST[ENCE] CONSTRAINTS

The NODE EXIST[ENCE] and EXIST[ENCE] type filtering options allowed by the SHOW CONSTRAINTS command now also return node label existence constraints (created as part of node element types in a graph type). For more information, see Syntax → Type filters.

Updated

SHOW CONSTRAINTS

The type column returned by SHOW CONSTRAINTS can now return three additional constraint types: NODE_LABEL_EXISTENCE, RELATIONSHIP_SOURCE_LABEL and RELATIONSHIP_TARGET_LABEL. These new constraint types are created as part of node and relationship element types when setting a graph type. For more information, see Set graph types.

New

Feature Details

New

Added the performance-improving operator MergeUniqueNode.

MergeUniqueNode is similar to the Merge operator, but is used when there is a property uniqueness constraint on the property used in the MERGE statement.

New Preview

ALTER CURRENT GRAPH TYPE SET {
    (:Person => :Resident {name :: STRING NOT NULL}),
    (:Pet => :Resident&Animal {healthCertificate :: STRING, name :: STRING}),
    (:City => {name :: STRING NOT NULL, population :: INTEGER}),
    (:Resident)-[:LIVES_IN => {since :: DATE NOT NULL}]->(:City)
}

Introduced the ability to set a graph type for a database using the ALTER CURRENT GRAPH TYPE SET command. A graph type enforces holistically an open schema, providing a defined structure for an entire graph, and includes constraint types (node label existence, relationship source node, and relationship target node constraints) not possible to create using the older CREATE CONSTRAINT syntax. For more information, see Set graph types.

New Preview

ALTER CURRENT GRAPH TYPE ADD {
  (p:Person => :Resident {name :: STRING, ssn :: INTEGER, nationality :: STRING})
    REQUIRE (p.name, p.ssn) IS KEY,
  CONSTRAINT pet_address FOR (pet:Pet) REQUIRE pet.address IS NOT NULL,
  (:Animal => {type :: STRING NOT NULL})
}

Introduced the ability to extend graph types using the ALTER CURRENT GRAPH TYPE ADD command. For more information, see Extend graph types.

New Preview

ALTER CURRENT GRAPH TYPE ALTER {
    (:Robot => :Resident&Machine {application :: STRING NOT NULL, id :: INTEGER NOT NULL}),
    (:Resident)-[:LIVES_IN => {since :: ANY NOT NULL}]->(:City)
}

Introduced the ability to alter element types in a graph type using the ALTER CURRENT GRAPH TYPE ALTER command. For more information, see Alter element types.

New Preview

SHOW CURRENT GRAPH TYPE

Introduced the ability to show graph types using the SHOW CURRENT GRAPH TYPE command. For more information, see Show graph types.

New Preview

ALTER CURRENT GRAPH DROP {
  (:Pet =>),
  CONSTRAINT pet_address
}

Introduced the ability to drop element types and constraints from graph types using the ALTER CURRENT GRAPH TYPE DROP command. For more information, see Drop graph type elements.

New GQL naming aliases for functions

RETURN ceiling(1.2) AS c, ln(2.0) AS natural_log,
       char_length("Hello") AS len, lower("Neo4j") AS lower, upper("Neo4j") AS upper;
RETURN local_time() AS t, local_datetime() AS ldt,
       zoned_time() AS zt, zoned_datetime() AS zdt;
RETURN duration_between(date("2020-01-01"), date("2020-02-01")) AS d;
MATCH p = (a)-[r]->(b)
RETURN path_length(p) AS path_len;
UNWIND [1, 2, 3] AS n
RETURN collect_list(n) AS list,
       percentile_cont(n, 0.5) AS p50,
       percentile_disc(n, 0.5) AS p50_disc,
       stdev_samp(n) AS sd_samp,
       stdev_pop(n) AS sd_pop;

Cypher now provides GQL naming aliases so that queries written for other GQL implementations can run with minimal changes. Aliases added: ceiling(), local_time(), local_datetime(), zoned_time(), zoned_datetime(), duration_between(), path_length(), ln(), collect_list(), percentile_cont(), percentile_disc(), stdev_samp() and stdev_pop().

Neo4j 2026.01

Updates

Feature Details

New

CREATE VECTOR INDEX multiLabel
FOR (n:Label1|Label2)
ON n.embedding
OPTIONS {indexConfig: {`vector.dimensions`: 1536, `vector.similarity_function`: 'cosine'}}
CREATE VECTOR INDEX multiRelType
FOR ()-[r:REL_TYPE1|REL_TYPE2]-()
ON r.embedding
OPTIONS {indexConfig: {`vector.dimensions`: 1536, `vector.similarity_function`: 'cosine'}}
CREATE VECTOR INDEX additionalProperties
FOR (n:Label)
ON n.embedding
WITH [n.property1, n.property2]
OPTIONS {indexConfig: {`vector.dimensions`: 1536, `vector.similarity_function`: 'cosine'}}

Vector indexes can now have multiple labels, relationship types or include additional properties for filtering.

New

Feature Details

New

MATCH (n)
  SEARCH n IN (
    VECTOR INDEX nodeVectorIndex
    FOR $vectorEmbedding
    WHERE n.prop > 10
    LIMIT 5
  )
RETURN n
MATCH ()-[r]->()
  SEARCH r IN (
    VECTOR INDEX relVectorIndex
    FOR $vectorEmbedding
    LIMIT 5
  )
RETURN r

A new SEARCH subclause for MATCH and OPTIONAL MATCH has been added which is used for filtering the results based on vector similarity.

New

Introduced a query size limit.

Introduced a query size limit for a query to be considered for query caching. This limit is used to prevent large generated query text strings from occupying memory in the query cache.

Neo4j 2025.12

No documentation updates for this release.

Neo4j 2025.11

Updates

Feature Details

Updated

label,name
Actor,Henry Cavill
CREATE RANGE INDEX actor_has_name FOR (a:Actor) ON (a.name);

LOAD CSV WITH HEADERS FROM 'people.csv' AS row
MERGE (:$(row.label) { name: row.name })

Cypher can now leverage indexes on property values, improving the performance of MATCH and MERGE when doing so, however:

  • It only supports exact seeks on range indexes (no full text or spatial).

  • The index order cannot be leveraged, so the planner must insert separate ordering if required later on in the query.

  • Parallel runtime seeks and scans are single-threaded.

  • The planner doesn’t combine multiple property index seeks when generating the results for the dynamic part of the query.

New

Feature Details

New

RETURN coll.distinct([true, false, false, true, true, false])
RETURN coll.flatten([1, [2]]), coll.flatten([false, ['a']], 2);
RETURN coll.indexOf(['A', 'new', 'function'], 'new');
RETURN coll.insert([1, 2, 4], 2, 3);
RETURN coll.max([1.5, 2, 5.4, 0, 4]);
RETURN coll.min([1.5, 2, 5.4, 0, 4]);
RETURN coll.remove(['a', 'a', 'b', 'c', 'd'], 2);
RETURN coll.sort([3, 1, 4, 2, 'a', 'c', 'b']);

Introduction of eight new collection-based Cypher functions. For more information, see Functions → List functions.

New

Added the performance-improving operatorsMergeInto .

MergeInto is similar to the Merge operator, but it is used when the start and end node of the pattern are matched outside the MERGE pattern.

Neo4j 2025.10

Updates

Feature Details

Updated

RETURN toFloatList(Vector([1, 2, 3], 3, INTEGER64)),
       toIntegerList(Vector([1, 2, 3], 3, INTEGER8)),
       vector.similarity.cosine(vector([3, 5, 7], 3, INT), vector([-1, -2, -3], 3, INT)),
       vector.similarity.euclidean(vector([3, 5, 7], 3, INT), vector([-1, -2, -3], 3, INT))

The toFloatList(), toIntegerList(), vector.similarity.cosine(), and vector.similarity.euclidean() functions now accept VECTOR values as input arguments.

Updated

RETURN datetime('11/18/1986', "MM/dd/yyyy") AS dt

The following constructors of temporal types have been extended with the optional argument pattern: date(), datetime(), localdatetime(), localtime(), time() and duration(). These patterns are the same as those used to create temporal strings with the format() function introduced in 2025.09 and thus allow for the parsing of temporal strings into temporal values.

New

Feature Details

New

VECTOR([1.05, 0.123, 5], 3, FLOAT32 NOT NULL)

Introduced a VECTOR value type that can be stored as embedding properties on nodes and relationships and utilized for efficient semantic retrieval using Neo4j’s vector indexes and GenAI plugin. For more information, see Values and types → Vectors.

New

WITH vector([1, 2, 3], 3, INTEGER) AS vector
RETURN vector, valueType(vector) AS vectorType

New vector() function for the construction of VECTOR values.

New

RETURN vector_dimension_count(vector([1, 2, 3], 3, INTEGER)) AS size

New vector_dimension_count() function, which returns the dimension of a VECTOR value.

New

RETURN vector_distance(vector([1, 2, 3], 3, INT), vector([1, 2, 4], 3, INT), COSINE) AS distance

New vector_distance() function, which returns the distance between two VECTOR values based on the selected vectorDistanceMetric algorithm.

New

RETURN vector_norm(vector([1.0, 5.0, 3.0, 6.7], 4, FLOAT), EUCLIDEAN) AS norm

New vector_norm() function, which returns the distance between the given vector and an origin vector, which is a vector with the same dimension with all coordinates set to zero, calculated using the specified vectorDistanceMetric.

New

CREATE CONSTRAINT node_vector_constraint
FOR (n:Movie) REQUIRE n.embedding IS :: VECTOR<INT32>(42)
CREATE CONSTRAINT rel_vector_constraint
FOR ()-[r:CONTAINS]->() REQUIRE r.embedding IS :: VECTOR<FLOAT32>(1536)

Introduced VECTOR property type constraints. For more information, see Create property type constraints.

Neo4j 2025.09

New

Feature Details

New

WITH datetime('1986-11-18T6:04:45.123456789+01:00[Europe/Berlin]') AS dt
RETURN format(dt, "MM/dd/yyyy") AS US, format(dt, "dd/MM/yyyy") AS EU

Cypher’s new format() function can create dynamically formatted string representations of temporal instance and duration types.

New

New operator: LockNodes

Introduced LockNodes operator, sometimes used in conjunction with the LockingMerge operator to lock nodes.

Neo4j 2025.08

Updates

Feature Details

Updated

MATCH (p:Product) WHERE p.name <> "Coffee"
CALL (p) {
    MATCH (p)<-[:BUYS]-(c:Customer)-[:BUYS]->(otherProduct)
    RETURN c, otherProduct
    NEXT
    RETURN count(DISTINCT c) AS customers, 0 AS customersAlsoBuyingCoffee
    UNION
    FILTER otherProduct.name = "Coffee"
    RETURN 0 as customers, count(DISTINCT c) AS customersAlsoBuyingCoffee
    NEXT
    RETURN max(customers) AS customers, max(customersAlsoBuyingCoffee) AS customersAlsoBuyingCoffee
}
RETURN p.name AS product,
       round(toFloat(customersAlsoBuyingCoffee) * 100 / customers, 1) AS percentageOfCustomersAlsoBuyingCoffee
  ORDER BY product

NEXT now correctly supports aggregations in the context of UNION and CALL. For more information, see Sequential queries (NEXT) > Known issues and fixes.

Updated

PROFILE
WITH "Person" AS label
MATCH (people:$(label))
RETURN people.name

Cypher can now leverage token lookup indexes when planning queries with dynamic labels and relationship types. This is enabled by the introduction of three new query plan operators: DynamicLabelNodeLookup, DynamicDirectedRelationshipTypeLookup, and DynamicUndirectedRelationshipTypeLookup.

New

Feature Details

New

MATCH (()-->(n))+
WHERE allReduce(acc = 0, node IN n | acc + node.x, 6 < acc < 30)
RETURN [i IN n | i.x] AS sequence
ORDER BY head(n).x, size(n)

New allReduce() function. It enables the stepwise evaluation of a value accumulated over a path, allowing for early pruning of paths that do not satisfy a given predicate, and is optimized for path expansions.

Neo4j 2025.07

Updates

Feature Details

Updated

MATCH (n)-[r]->()
WHERE n:$(<expr1>)
WITH n, r:$(<expr2>) AS hasType
RETURN n:$(<expr3>)

Added the ability to dynamically reference node labels and relationship types in places where label expressions are allowed.

Neo4j 2025.06

Removals

Feature Details

Removed

CREATE DATABASE db OPTIONS { seedCredentials: ... }

The option seedCredentials is removed from the CREATE DATABASE OPTIONS map. For more information, see Operations Manual → Database administration → Create databases.

Removed

CREATE DATABASE db OPTIONS { existingDataSeedInstance: ... }

The option existingDataSeedInstance is removed from the CREATE DATABASE OPTIONS map and replaced by existingDataSeedServer. For more information, see Operations Manual → Database administration → Create databases.

Removed

CREATE ALIAS composite.`1` FOR DATABASE neo4j
USE composite.`1`

Graph references with separately backticked name parts have been removed. Use parameters or backtick the entire name, e.g. USE `composite.1`

Removed

RETURN 1 as my\u0085identifier

The Unicode character \u0085 (Next Line) has been removed for unescaped identifiers and is now considered a whitespace character. To continue using it, escape the identifier by adding backticks (``) around it. This applies to all unescaped identifiers in Cypher, such as label expressions, properties, variable names, or parameters. In the given example, the quoted identifier would be my\u0085identifier.

Removed

RETURN 1 as my$Identifier

The character with the Unicode representation \u0024 ($) has been removed for unescaped identifiers. To continue using it, escape the identifier by adding backticks (``) around the identifier. This applies to all unescaped identifiers in Cypher, such as label expressions, properties, variable names, or parameters. In the given example, the quoted identifier would be my\u0024identifier.

The following Unicode Characters are removed in identifiers: \u0000, \u0001, \u0002, \u0003, \u0004, \u0005, \u0006, \u0007, \u0008, \u000E, \u000F, \u0010, \u0011, \u0012, \u0013, \u0014, \u0015, \u0016, \u0017, \u0018, \u0019, \u001A, \u001B, \u007F, \u0080, \u0081, \u0082, \u0083, \u0084, \u0086, \u0087, \u0088, \u0089, \u008A, \u008B, \u008C, \u008D, \u008E, \u008F, \u0090, \u0091, \u0092, \u0093, \u0094, \u0095, \u0096, \u0097, \u0098, \u0099, \u009A, \u009B, \u009C, \u009D, \u009E, \u009F, \u0024, \u00A2, \u00A3, \u00A4, \u00A5, \u00AD, \u0600, \u0601, \u0602, \u0603, \u0604, \u0605, \u061C, \u06DD, \u070F, \u08E2, \u180E, \u200B, \u200C, \u200D, \u200E, \u200F, \u202A, \u202B, \u202C, \u202D, \u202E, \u2060, \u2061, \u2062, \u2063, \u2064, \u2066, \u2067, \u2068, \u2069, \u206A, \u206B, \u206C, \u206D, \u206E, \u206F, \u2E2F, \uFEFF, \uFFF9, \uFFFA, \uFFFB

Removed

MATCH (n)-[r:REL]->(m) SET n = r;
MATCH (n)-[r:REL]->(m) SET n += r;
MATCH (n)-[r:REL]->(m) SET r = n;
MATCH (n)-[r:REL]->(m) SET r += n;

Using a NODE or RELATIONSHIP instead of a MAP on the RHS of a SET properties clause is no longer supported. Instead, use the properties() function to get the map of properties from nodes or relationships, which can then be used in the SET clause.

MATCH (n)-[r:REL]->(m) SET n = properties(r)

Removed

REVOKE READ {*} ON GRAPH * NODES A FROM missingUser
REVOKE ROLE missingRole FROM bob

Errors have replaced notifications for impossible REVOKE commands where a user, role, or database does not exist.

Removed

MERGE (a {foo:1})-[:T]->(b {foo:a.foo})

It is no longer possible to specify a property of one entity (node or relationship) by referring to another entity’s property within the same MERGE clause.

Removed

CREATE ... INDEX ... OPTIONS { indexProvider: ... }
CREATE ... CONSTRAINTS ... OPTIONS { indexProvider: ... }

Specifying an index provider in the OPTIONS map when creating an index or constraint is no longer supported.

Removed

db.create.setVectorProperty()
db.index.vector.createNodeIndex()
dbms.cluster.readReplicaToggle()
dbms.cluster.uncordonServer()
dbms.quarantineDatabase()
dbms.upgrade()
dbms.upgradeStatus()

These procedures have been removed from Cypher 25. For more information, see the Operations Manual → Procedures.

Deprecations

Feature Details

Deprecated

CREATE DATABASE db OPTIONS { existingData: ... }

The option existingData is deprecated. For more information, see Operations Manual → Database administration → Create databases.

Updates

Feature Details

Updated

WITH 1 AS g
RETURN COLLECT {
        UNWIND [1,2,3] AS x
        WITH * WHERE x < 0
        WITH count(*) AS agg
        RETURN agg + g
} AS x

Imported variables are now correctly handled as constants inside COLLECT, COUNT, and EXISTS subquery expressions. The example query previously returned no results ([]) because the imported variable was used incorrectly as an implicit grouping key. It now returns [1], since the variable is not used as a grouping key, allowing count(*) to return 0 and 0 + g to evaluate to 1.

Updated

RETURN $0hello

Parameters can start with extended identifier characters (such as numbers), in line with the GQL standard. For more information, see Parameters.

Updated

MATCH SHORTEST $param (:A)-[:R]->{0,10}(:B)
MATCH p = ANY $param (:A)-[:R]->{0,10}(:B)
MATCH SHORTEST $param GROUPS (:A)-[:R]->{0,10}(:B)

Parameters can now be used in SHORTEST and ANY path patterns.

Updated

CALL db.schema.nodeTypeProperties() YIELD propertyTypes RETURN propertyTypes;
CALL db.schema.relTypeProperties() YIELD propertyTypes RETURN propertyTypes;

The column propertyTypes returned by the procedures db.schema.nodeTypeProperties() and db.schema.relTypeProperties() previously returned a list of strings representing the potential Java types for a given property. It now returns a list of strings representing the possible Cypher Types the given property has. For all available Cypher types, see the section on types and their synonyms.

Syntax Updated

SHOW NODE PROPERTY UNIQUENESS CONSTRAINTS
SHOW RELATIONSHIP PROPERTY UNIQUENESS CONSTRAINTS
SHOW PROPERTY UNIQUENESS CONSTRAINTS

The constraint type keyword filtering for SHOW CONSTRAINTS now allows the optional keyword PROPERTY when filtering on property uniqueness constraints. The constraint type column returned is also updated to return NODE_PROPERTY_UNIQUENESS and RELATIONSHIP_PROPERTY_UNIQUENESS.

Updated

SHOW TRANSACTIONS YIELD startTime, clientAddress, outerTransactionId, currentQuery, currentQueryId, parameters, planner, runtime, indexes, currentQueryStartTime, currentQueryElapsedTime, currentQueryCpuTime, currentQueryIdleTime, currentQueryStatus

Several SHOW TRANSACTIONS columns have been updated:

  • startTime and currentQueryStartTime now return a ZONED DATETIME instead of a STRING representation of a temporal value.

  • clientAddress and outerTransactionId now return null instead of an empty STRING when unavailable.

  • The current query-related columns — currentQuery, currentQueryId, parameters, planner, runtime, indexes, currentQueryStartTime, currentQueryElapsedTime, currentQueryCpuTime, currentQueryIdleTime, and currentQueryStatus — now return null when no query is executing.

For more information, see the Operations Manual → Show and terminate transactions.

Updated

USE graph.byName('composite.with.dot.constituent')
USE graph.propertiesByName('composite.with.dot.constituent')

Graph references in the arguments of the functions graph.byName and graph.propertiesByName now require no syntactic quotes.

In Cypher 5, if a composite database or constituent name contains dots, those name parts have to be wrapped in quotes to resolve the name correctly, e.g., USE graph.byName('`composite.with.dot`.constituent').

Updated

CREATE (:Person)
MATCH (p:Person)
RETURN count(p) AS count

Queries no longer require WITH to transition between reading and writing operations. For more information, see Clause composition → Read-write queries.

Updated

RETURN replace("hello world", "l", "", 1)

The replace() function now accepts an optional limit argument, defining the number of times the search string is replaced.

New

Feature Details

New

CREATE [COMPOSITE] DATABASE actors SET DEFAULT LANGUAGE CYPHER 25

Set the default Cypher version for a standard or composite database when creating it. The available versions are CYPHER 25 and CYPHER 5. If not specified, the default language for the database is set to the default language of the DBMS. For more information, see the following sections in the Operations Manual:

New

CREATE ALIAS `remote-with-default-language`
FOR DATABASE `northwind-graph-2020`
    AT "neo4j+s://location:7687"
    USER alice
    PASSWORD 'example_secret'
    DEFAULT LANGUAGE CYPHER 25

Set the default Cypher version for a remote database alias when creating it. The available versions are CYPHER 5 and CYPHER 25. Local database aliases and database aliases in composite databases cannot be assigned a default Cypher version. Local database aliases always have the Cypher version of their target database and database aliases in composite databases always have the Cypher version of the composite database they belong to. For more information, see the Operations Manual → Set a default Cypher version for remote database aliases.

New

ALTER DATABASE movies SET DEFAULT LANGUAGE CYPHER 25

Alter the default Cypher version of an existing standard or composite database. The available versions are CYPHER 25 and CYPHER 5. For more information, see the Operations Manual → Alter the default Cypher version of an existing database.

New

ALTER ALIAS `remote-with-default-language` SET DATABASE DEFAULT LANGUAGE CYPHER 25

Alter the default Cypher version of a remote database alias. The available versions are CYPHER 25 and CYPHER 5. It is not possible to alter the default Cypher version of a local database alias or an alias belonging to a composite database. Local database aliases always have the Cypher version of their target database and aliases belonging to composite databases always have the Cypher version of the composite database. For more information, see the Operations Manual → Alter the default Cypher version of a remote database alias.

New

SHOW DATABASES YIELD name, defaultLanguage

The new return column defaultLanguage for the SHOW DATABASE command returns the default language of a database. This column is not returned by default; it can only be returned using YIELD. For more information, see the Operations Manual → Show the default Cypher version of a database.

New

SHOW ALIAS `remote-with-default-language` FOR DATABASE YIELD name, defaultLanguage

The new return column defaultLanguage for the SHOW ALIAS command returns the default language of a database alias. This column is not returned by default; it can only be returned using YIELD. For more information, see the Operations Manual → List database aliases.

New

CYPHER 25
MATCH (n:Person)
FILTER n.age < 35
RETURN n.name AS name

New query option: CYPHER 25. Prepending a query with CYPHER 25 ensures that a query is run with Cypher 25, regardless of the default language of a database. (The ability to select CYPHER 5 was introduced in Neo4j 5.21).

New

RETURN 1 AS a

NEXT

RETURN 1 AS b

New NEXT keyword used for linear composition of queries. For more information, see Sequential queries (NEXT).

New

MATCH (s:Supplier)-[:SUPPLIES]->(p:Product)
LET supplier =  s.name
RETURN supplier, p.name AS product

New LET clause used to bind values to variables.

New

UNWIND [1, 2, 3, 4, 5, 6] AS x
FILTER x > 2
RETURN x
LOAD CSV WITH HEADERS FROM 'file:///companies.csv' AS row
FILTER row.Id IS NOT NULL
MERGE (c:Company {id: row.Id})

New FILTER clause used to filter queries, similar to WHERE.

New

WHEN false THEN RETURN 1 AS x
WHEN true THEN RETURN 2 AS x
ELSE RETURN 3 AS x
 MATCH (n:Person)
 OPTIONAL MATCH (n)-[:KNOWS]->(m)
 CALL (*) {
   WHEN m IS NULL THEN {
      CREATE (f: Person {name: 'Peter', age: n.age}),
      (n)-[:KNOWS]->(f)
         RETURN f, n.name AS newConnection
   }
 }
RETURN f.name AS newNode,
       collect(newConnection) AS newConnections

Introduction of WHEN/ELSE branches which enable the composition of conditional queries, similar to the IF statement in other programming languages. For more information, see Conditional queries (WHEN).

New

{
   MATCH (n:Actor)
   RETURN n.name AS name
   UNION
   MATCH (n:Director)
   RETURN n.name AS name
}
UNION ALL
MATCH (n:Movie)
RETURN n.title AS name

UNION [DISTINCT] and UNION ALL can now be combined in the same query by using curly braces. For more information, see Combining UNION and UNION ALL.

New

CREATE DATABASE db OPTIONS { seedRestoreUntil: ... }

The option seedRestoreUntil can now be specified in the CREATE DATABASE OPTIONS map. This allows a database to be seeded up to a specific date or transaction ID. For more information, see Operations Manual → Database administration → Create a database from a URI.

New

CREATE DATABASE db OPTIONS { seedSourceDatabase: ... }

You can specify the name of a source database if the seedURI points to a folder containing backups for multiple databases. For more information, see Operations Manual → Database administration → Create databases.

New

RETURN cosh(0.5), coth(0.5), sinh(0.5), tanh(0.5)

Introduction of four new hyperbolic trigonometric Cypher functions. For more information, see Mathematical functions - trigonometric.

New

MATCH (n)
RETURN ALL n.prop AS prop

The keyword ALL can now be added after a RETURN as the explicit form of a RETURN without duplicate removal.

New

MATCH (n)
WITH ALL n.prop AS prop
RETURN prop

The keyword ALL can now be added after a WITH as the explicit form of a WITH without duplicate removal.

New

MATCH REPEATABLE ELEMENTS p = (:B)-->{,5}()
RETURN [n IN nodes(p) | n.q] AS nodes

Introduction of REPEATABLE ELEMENTS, which ensures that relationships as well as nodes can be repeatedly traversed in a graph pattern.

New

MATCH DIFFERENT RELATIONSHIPS p = (:B)-->{,5}()
RETURN [n IN nodes(p) | n.q] AS nodes

New keyword, DIFFERENT RELATIONSHIPS, which enables explicitly specifying Cypher’s default behavior of not allowing relationships to be re-traversed in a graph pattern.