SHOW

The SHOW command can be used to show the metadata of a database or a DBMS. This page discusses common behavior to all SHOW commands. Rules pertaining to specific SHOW commands, as well as the different columns returned by them, are listed on other pages or in the Operations Manual as follows:

Common behavior and rules

All SHOW commands have similar behavior and comply to the same rules.

Returning default and non-default columns using SHOW and YIELD

All SHOW commands have default return columns, and most have non-default return columns as well. For information about the specific columns, visit the documentation for the specific SHOW command listed above.

Using YIELD returns non-default columns, either specific columns or all available columns.

Show indexes — return only default columns
SHOW INDEXES
Show indexes — return specific columns with YIELD
SHOW INDEXES
YIELD name, type, indexProvider
Show indexes — return all available columns using YIELD *
SHOW INDEXES
YIELD *

Using SHOW commands with RETURN

If the RETURN clause is used in any SHOW command, YIELD is mandatory.

RETURN after YIELD
SHOW INDEXES
YIELD name, type, indexProvider AS provider, options, createStatement
RETURN name, type, provider, options.indexConfig AS config, createStatement

Filter SHOW commands using WHERE

All SHOW commands can be filtered using the WHERE clause. This allows you to narrow down results based on specific conditions, such as names or status values.

Filter SHOW command using WHERE
SHOW SETTINGS YIELD name, value, description
WHERE name STARTS WITH 'server'
RETURN name, value, description

Composable SHOW commands
Cypher 25 onlyIntroduced in 2026.05

The following SHOW commands can be combined with each other and other Cypher® clauses; see their respective sections for examples:

When combining a SHOW command with other clauses, the YIELD clause is mandatory and must not be omitted. YIELD must explicitly list the yielded columns. YIELD * is not permitted. The query must also end with a valid last clause (like a RETURN or an updating clause).
Return all functions and procedures
SHOW PROCEDURES
YIELD name, signature
RETURN name, signature, 'procedure' AS type
UNION
SHOW FUNCTIONS
YIELD name, signature
RETURN name, signature, 'function' AS type
Return all functions with more than one signature
SHOW FUNCTIONS
YIELD name, signature
WITH name, collect(signature) AS signatures
FILTER size(signatures) > 1
RETURN name, signatures