Breadth First Search

Supported algorithm traits:

1. Introduction

The Breadth First Search algorithm is a graph traversal algorithm that given a start node visits nodes in order of increasing distance, see https://en.wikipedia.org/wiki/Breadth-first_search. A related algorithm is the Depth First Search algorithm, Depth First Search. This algorithm is useful for searching when the likelihood of finding the node searched for decreases with distance. There are multiple termination conditions supported for the traversal, based on either reaching one of several target nodes, reaching a maximum depth, exhausting a given budget of traversed relationship cost, or just traversing the whole graph. The output of the procedure contains information about which nodes were visited and in what order.

2. Syntax

Breadth First Search syntax per mode
Run Breadth First Search in stream mode:
CALL gds.bfs.stream(
  graphName: string,
  configuration: map
)
YIELD
  sourceNode: int,
  nodeIds: int,
  path: Path
Table 1. Parameters
Name Type Default Optional Description

graphName

String

n/a

no

The name of a graph stored in the catalog.

configuration

Map

{}

yes

Configuration for algorithm-specifics and/or graph filtering.

Table 2. General configuration
Name Type Default Optional Description

concurrency

Integer

4

yes

The number of concurrent threads used for running the algorithm. Also provides the default value for 'readConcurrency' and 'writeConcurrency'.

writeConcurrency

Integer

value of 'concurrency'

yes

The number of concurrent threads used for writing the result (applicable in WRITE mode).

Table 3. Algorithm specific configuration
Name Type Default Optional Description

sourceNode

Integer

n/a

no

The node id of the node where to start the traversal.

targetNodes

List of Integer

empty list

yes

Ids for target nodes. Traversal terminates when any target node is visited.

maxDepth

Integer

-1

yes

The maximum distance from the source node at which nodes are visited.

Table 4. Results
Name Type Description

sourceNode

Integer

The node id of the node where to start the traversal.

nodeIds

List of Integer

The ids of all nodes that were visited during the traversal.

path

Path

A path containing all the nodes that were visited during the traversal.

Run Breadth First Search in stream mode:
CALL gds.bfs.mutate(
  graphName: string,
  configuration: map
)
YIELD
  relationshipsWritten: Integer,
  preProcessingMillis: Integer,
  computeMillis: Integer,
  postProcessingMillis: Integer,
  mutateMillis: Integer,
  configuration: Map
Table 5. Parameters
Name Type Default Optional Description

graphName

String

n/a

no

The name of a graph stored in the catalog.

configuration

Map

{}

yes

Configuration for algorithm-specifics and/or graph filtering.

Table 6. General configuration for algorithm execution.
Name Type Default Optional Description

nodeLabels

List of String

['*']

yes

Filter the named graph using the given node labels.

relationshipTypes

List of String

['*']

yes

Filter the named graph using the given relationship types.

concurrency

Integer

4

yes

The number of concurrent threads used for running the algorithm.

mutateRelationshipType

String

n/a

no

The relationship type used for the new relationships written to the projected graph.

Table 7. Algorithm specific configuration
Name Type Default Optional Description

sourceNode

Integer

n/a

no

The node id of the node where to start the traversal.

targetNodes

List of Integer

empty list

yes

Ids for target nodes. Traversal terminates when any target node is visited.

maxDepth

Integer

-1

yes

The maximum distance from the source node at which nodes are visited.

Table 8. Results
Name Type Description

preProcessingMillis

Integer

Milliseconds for preprocessing the graph.

computeMillis

Integer

Milliseconds for running the algorithm.

postProcessingMillis

Integer

Unused.

mutateMillis

Integer

Milliseconds for adding relationships to the projected graph.

relationshipsWritten

Integer

The number of relationships that were added.

configuration

Map

The configuration used for running the algorithm.

Run Breadth First Search in stats mode:
CALL gds.bfs.stats(
  graphName: string,
  configuration: map
)
YIELD
  preProcessingMillis: Integer,
  computeMillis: Integer,
  postProcessingMillis: Integer,
  configuration: Map
Table 9. Parameters
Name Type Default Optional Description

graphName

String

n/a

no

The name of a graph stored in the catalog.

configuration

Map

{}

yes

Configuration for algorithm-specifics and/or graph filtering.

Table 10. General configuration for algorithm execution.
Name Type Default Optional Description

nodeLabels

List of String

['*']

yes

Filter the named graph using the given node labels.

relationshipTypes

List of String

['*']

yes

Filter the named graph using the given relationship types.

concurrency

Integer

4

yes

The number of concurrent threads used for running the algorithm.

Table 11. Algorithm specific configuration
Name Type Default Optional Description

sourceNode

Integer

n/a

no

The node id of the node where to start the traversal.

targetNodes

List of Integer

empty list

yes

Ids for target nodes. Traversal terminates when any target node is visited.

maxDepth

Integer

-1

yes

The maximum distance from the source node at which nodes are visited.

Table 12. Results
Name Type Description

preProcessingMillis

Integer

Milliseconds for preprocessing the graph.

computeMillis

Integer

Milliseconds for running the algorithm.

postProcessingMillis

Integer

Unused.

configuration

Map

The configuration used for running the algorithm.

3. Examples

In this section we will show examples of running the Breadth First Search algorithm on a concrete graph. The intention is to illustrate what the results look like and to provide a guide in how to make use of the algorithm in a real setting. We will do this on a small graph of a handful nodes connected in a particular pattern. The example graph looks like this:

Visualization of the example graph

Consider the graph projected by the following Cypher statement:

CREATE
       (nA:Node {name: 'A'}),
       (nB:Node {name: 'B'}),
       (nC:Node {name: 'C'}),
       (nD:Node {name: 'D'}),
       (nE:Node {name: 'E'}),

       (nA)-[:REL]->(nB),
       (nA)-[:REL]->(nC),
       (nB)-[:REL]->(nE),
       (nC)-[:REL]->(nD)
The following statement will project the graph and store it in the graph catalog.
CALL gds.graph.project('myGraph', 'Node', 'REL')

In the following examples we will demonstrate using the Breadth First Search algorithm on this graph.

3.1. Memory Estimation

First off, we will estimate the cost of running the algorithm using the estimate procedure. This can be done with any execution mode. We will use the stream mode in this example. Estimating the algorithm is useful to understand the memory impact that running the algorithm on your graph will have. When you later actually run the algorithm in one of the execution modes the system will perform an estimation. If the estimation shows that there is a very high probability of the execution going over its memory limitations, the execution is prohibited. To read more about this, see Automatic estimation and execution blocking.

For more details on estimate in general, see Memory Estimation.

The following will estimate the memory requirements for running the algorithm in stream mode:
MATCH (source:Node {name: 'A'})
CALL gds.bfs.stream.estimate('myGraph', {
    sourceNode: source
})
YIELD nodeCount, relationshipCount, bytesMin, bytesMax, requiredMemory
RETURN nodeCount, relationshipCount, bytesMin, bytesMax, requiredMemory
Table 13. Results
nodeCount relationshipCount bytesMin bytesMax requiredMemory

5

4

536

536

"536 Bytes"

3.2. Stream

In the stream execution mode, the algorithm returns the path in traversal order for each relationship. This allows us to inspect the results directly or post-process them in Cypher without any side effects.

For more details on the stream mode in general, see Stream.

The following will run the algorithm and stream results:
MATCH (source:Node{name:'A'})
CALL gds.bfs.stream('myGraph', {
  sourceNode: source
})
YIELD path
RETURN path

If we do not specify any of the options for early termination, the algorithm will traverse the entire graph. In the image below we can see the traversal order of the nodes, marked by relationship type NEXT:

Visualization of Breadth First Search stream without early termination conditions
Running the Breadth First Search algorithm with target nodes:
MATCH (a:Node{name:'A'}), (d:Node{name:'D'}), (e:Node{name:'E'})
WITH id(a) AS source, [id(d), id(e)] AS targetNodes
CALL gds.bfs.stream('myGraph', {
  sourceNode: source,
  targetNodes: targetNodes
})
YIELD path
RETURN path

In the image below we can see the traversal order of the nodes, marked by relationship type NEXT. It is notable that the D node is not present in the picture, this is because the algorithm reached the target node E first and terminated the execution, leaving D unvisited.

Visualization of Breadth First Search stream with target nodes
Running the Breadth First Search algorithm with maxDepth:
MATCH (source:Node{name:'A'})
CALL gds.bfs.stream('myGraph', {
  sourceNode: source,
  maxDepth: 1
})
YIELD path
RETURN path

In the image below we can see the traversal order of the nodes, marked by relationship type NEXT. Nodes D and E were not visited since they are at distance 2 from node A.

Visualization of Breadth First Search stream with max depth

3.3. Mutate

The mutate execution mode updates the named graph with new relationships. The path returned from the Breadth First Search algorithm is a line graph, where the nodes appear in the order they were visited by the algorithm. The relationship type has to be configured using the mutateRelationshipType option.

The mutate mode is especially useful when multiple algorithms are used in conjunction.

For more details on the mutate mode in general, see Mutate.

Breadth First Search mutate supports the same early termination conditions as the stream mode.

The following will run the algorithm in mutate mode:
MATCH (source:Node{name:'A'})
CALL gds.bfs.mutate('myGraph', {
  sourceNode: source,
  mutateRelationshipType: 'BFS'
})
YIELD relationshipsWritten
RETURN relationshipsWritten
Table 14. Results
relationshipsWritten

4

After executing the above query, the in-memory graph will be updated with new relationships of type BFS.

The relationships produced are always directed, even if the input graph is undirected.