Salesforce Agentforce — Multi-Agent Integration with Aura Agents

MATCH (n)
UNWIND labels(n) AS label
RETURN label, count(*) AS nodes
ORDER BY label;

MATCH ()-[r]->()
RETURN type(r) AS relationshipType, count(*) AS relationships
ORDER BY relationshipType;

MATCH (c:Customer)
WHERE c.contactName = 'Thomas Hardy'
  AND c.companyName = 'Around the Horn'
RETURN c.customerID, c.contactName, c.companyName;

MATCH (c:Customer {customerID: 'AROUT'})-[:PURCHASED]->(o:Order)-[line:ORDERS]->(p:Product)
WHERE p.unitsInStock = 0 OR p.discontinued = true
RETURN p.productName,
       count(DISTINCT o) AS orderCount,
       sum(line.quantity) AS quantity,
       p.unitsInStock,
       p.unitsOnOrder,
       p.discontinued
ORDER BY orderCount DESC, quantity DESC;

You are a Northwind service-recovery expert for internal customer
service representatives.

For a product-recovery request:
1. Require both the contact name and company name. Never guess a customer.
2. Call Recommend customer-familiar product options with those two values.
3. If the tool returns no result, ask the representative to verify the exact
   contact and company names. Do not return information about another customer.
4. Treat the usual unavailable product returned by the tool as the inferred
   product. Explain the evidence: distinct historical orders and total quantity.
5. Explain whether the product is out of stock, discontinued, or both. Mention
   units on order, but never invent an arrival or restock date.
6. Recommend no more than three returned options. Prefer options marked
   previouslyPurchased. If customer-familiar options exist, recommend those
   before unfamiliar same-category options.
7. Describe results as in-stock options or customer-familiar options. Do not
   claim that same-category products are equivalent substitutes.
8. Return two short sections: Recommendation and Reasoning.
9. Use only facts returned by the tool. Never expose customer addresses, phone
   numbers, fax numbers, or information about unrelated customers.

Use when supplied both a customer's contact name and company name and asked about the usual unavailable product.
The tool requires an exact case-insensitive match on both names. It identifies the historically most frequently ordered product that is now out of stock or discontinued, then returns up to three active, in-stock products from the same category, prioritizing products the customer previously ordered. Do not use for customer searches that omit either name or for unrelated Northwind questions.

MATCH (customer:Customer)
WHERE toLower(trim(customer.contactName)) = toLower(trim($contactName))
  AND toLower(trim(customer.companyName)) = toLower(trim($companyName))
WITH collect(customer) AS customerMatches
WHERE size(customerMatches) = 1
WITH head(customerMatches) AS customer
MATCH (customer)-[:PURCHASED]->(sourceOrder:Order)-[sourceLine:ORDERS]->(source:Product)
WHERE source.unitsInStock = 0 OR source.discontinued = true
WITH customer,
     source,
     count(DISTINCT sourceOrder) AS sourceOrderCount,
     sum(sourceLine.quantity) AS sourceQuantity,
     max(sourceOrder.orderDate) AS lastSourceOrderDate
ORDER BY sourceOrderCount DESC,
         sourceQuantity DESC,
         lastSourceOrderDate DESC,
         source.productName ASC
WITH customer,
     collect({
       product: source,
       orderCount: sourceOrderCount,
       quantity: sourceQuantity,
       lastOrderDate: lastSourceOrderDate
     })[0] AS usual
WITH customer, usual, usual.product AS source
MATCH (source)-[:PART_OF]->(category:Category)<-[:PART_OF]-(candidate:Product)
WHERE candidate <> source
  AND candidate.unitsInStock > 0
  AND candidate.discontinued = false
OPTIONAL MATCH (customer)-[:PURCHASED]->(candidateOrder:Order)-[candidateLine:ORDERS]->(candidate)
WITH customer,
     usual,
     source,
     category,
     candidate,
     count(DISTINCT candidateOrder) AS candidateOrderCount,
     coalesce(sum(candidateLine.quantity), 0) AS candidateQuantity,
     max(candidateOrder.orderDate) AS lastCandidateOrderDate
ORDER BY CASE WHEN candidateOrderCount > 0 THEN 0 ELSE 1 END,
         candidateOrderCount DESC,
         lastCandidateOrderDate DESC,
         abs(candidate.unitPrice - source.unitPrice) ASC,
         candidate.unitsInStock DESC,
         candidate.productName ASC
WITH customer,
     usual,
     category,
     collect({
       productId: candidate.productID,
       productName: candidate.productName,
       quantityPerUnit: candidate.quantityPerUnit,
       unitPrice: candidate.unitPrice,
       unitsInStock: candidate.unitsInStock,
       unitsOnOrder: candidate.unitsOnOrder,
       previouslyPurchased: candidateOrderCount > 0,
       customerOrderCount: candidateOrderCount,
       customerQuantity: candidateQuantity,
       lastCustomerOrderDate: lastCandidateOrderDate
     })[0..3] AS options
RETURN customer.customerID AS customerId,
       customer.contactName AS contactName,
       customer.companyName AS companyName,
       usual.product.productID AS usualProductId,
       usual.product.productName AS usualProductName,
       usual.product.quantityPerUnit AS usualQuantityPerUnit,
       usual.product.unitPrice AS usualUnitPrice,
       usual.product.unitsInStock AS usualUnitsInStock,
       usual.product.unitsOnOrder AS usualUnitsOnOrder,
       usual.product.discontinued AS usualDiscontinued,
       usual.orderCount AS usualProductOrderCount,
       usual.quantity AS usualProductQuantity,
       usual.lastOrderDate AS usualProductLastOrderDate,
       category.categoryName AS category,
       options

Thomas Hardy from the company Around the Horn says their usual product is
unavailable. Review their purchasing history, identify suitable in-stock options
in the same category, and give me a grounded recommendation.

Recommendation
Gorgonzola Telino is Around the Horn's usual unavailable product. It is active
but currently out of stock. Offer Flotemysost first, followed by Camembert
Pierrot; Around the Horn has ordered both before and both are currently in stock.

Reasoning
Around the Horn ordered Gorgonzola Telino in 3 orders, 115 units in total. Its
current stock is 0, with 70 units on order. Flotemysost has 26 units in stock and
Camembert Pierrot has 19. These are customer-familiar Dairy Products, not
guaranteed equivalent substitutes.

Thomas Hardy from Ernst Handel needs an alternative to their usual product.

https://mcp.neo4j.io/agent?project_id=<PROJECT_ID>&agent_id=<AGENT_ID>

Order Recovery

Handles questions about a named customer, their purchase history, their usual unavailable product, current product inventory, and in-stock same-category options. Use when the user supplies both a contact name and company name.

1. Require a contact name and company name. If either is missing, ask for it.
2. Invoke the Northwind Aura Agent MCP action with the representative's complete
   product-recovery question.
3. Invoke the action once. If it reports that the identity cannot be matched,
   ask the representative to verify the names; do not guess.
4. Present the returned Recommendation and Reasoning concisely.
5. Preserve inventory, purchase-count, and limitation statements from the Aura
   response. Do not add unsupported product claims or restock dates.

Thomas Hardy from the company Around the Horn says their usual product is
unavailable. Review their purchasing history, identify suitable in-stock options
in the same category, and give me a grounded recommendation.