Set up and query composite databases
Enterprise EditionNot available on Aura

The examples featured in this section make use of the two Cypher clauses: USE and CALL {}.

Graph set-up

The following set-up is required to recreate the examples on this page:

Create a standard database movies-latest

Introduced in 2025.06

CREATE DATABASE `movies-latest`

Create a composite database cineasts

CREATE COMPOSITE DATABASE cineasts

Create database alias cineasts.latest for a local database in a composite database

CREATE ALIAS `cineasts.latest`
  FOR DATABASE `movies-latest`

Create database alias cineasts.upcoming for a remote database in a composite database

CREATE ALIAS `cineasts.upcoming`
  FOR DATABASE upcoming
  AT 'neo4j+s://location:7687'
  USER neo4j
  PASSWORD 'password'

Create a standard database movies-latest

CREATE DATABASE `movies-latest`

Create a composite database cineasts

CREATE COMPOSITE DATABASE cineasts

Create database alias cineasts.latest for a local database in a composite database

CREATE ALIAS `cineasts`.`latest`
  FOR DATABASE `movies-latest`

Create database alias cineasts.upcoming for a remote database in a composite database

CREATE ALIAS `cineasts`.`upcoming`
  FOR DATABASE upcoming
  AT 'neo4j+s://location:7687'
  USER neo4j
  PASSWORD 'password'

Cypher 5 is the version that is in use in Neo4j up to and including version 2025.05. For details, see Cypher® versions.

For more information about composite databases and database aliases in composite databases, see Concepts, and Managing database aliases in composite databases.

Graph selection

Queries submitted to a composite database may contain several USE clauses that direct different parts of the query to different constituent graphs.

Each constituent graph is named after the alias that introduces it into the Composite database.

Query a single graph

Example 1. Reading and returning data from a single graph

USE cineasts.latest
MATCH (movie:Movie)
RETURN movie.title AS title

The USE clause at the beginning of the query selects the cineasts.latest graph for all the subsequent clauses. MATCH is performed on that graph.

Query multiple graphs

Example 2. Reading and returning data from two graphs

USE cineasts.latest
MATCH (movie:Movie)
RETURN movie.title AS title
  UNION
USE cineasts.upcoming
MATCH (movie:Movie)
RETURN movie.title AS title

The first part of the UNION query selects the cineasts.latest graph and the second part selects the cineasts.upcoming graph.

Dynamic graph access

Queries can also select constituent graphs dynamically, using the form USE graph.byName(graphName).

Example 3. Reading and returning data from dynamically selected graphs

UNWIND ['cineasts.latest', 'cineasts.upcoming'] AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie.title AS title

In the example above, the part of the query accessing graph data, MATCH (movie:Movie), is wrapped in a sub-query with a dynamic USE clause. UNWIND is used to get the names of your graphs, each on one row. The CALL {} sub-query executes once per input row. In this case, once selecting cineasts.latest, and once selecting cineasts.upcoming.

Listing graphs

The built-in function graph.names() returns a list containing the names of all constituent graphs on the current Composite database.

Example 4. The graph.names() function

UNWIND graph.names() AS graphName
RETURN graphName

+---------------------+
| graphName           |
+---------------------+
| "cineasts.latest"   |
| "cineasts.upcoming" |
+---------------------+

The names returned by this function can be used for dynamic graph access.

Example 5. Reading and returning data from all graphs

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie.title

Query result aggregation

Example 6. Getting the earliest release year of all movies from all graphs

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie.released AS released
}
RETURN min(released) AS earliest

The sub-query returns the released property of each movie, from each constituent graph. The RETURN at the end of the main query aggregates across the full result to calculate the global minimum.

Correlated subqueries

This query finds all movies in cineasts.upcoming that are to be released in the same month as the longest movie in cineasts.latest.

Example 7. Correlated subquery

CALL {
  USE cineasts.latest
  MATCH (movie:Movie)
  RETURN movie.releasedMonth AS monthOfLongest
    ORDER BY movie.runningTime DESC
    LIMIT 1
}
CALL {
  USE cineasts.upcoming
  WITH monthOfLongest
  MATCH (movie:Movie)
  WHERE movie.releasedMonth = monthOfLongest
  RETURN movie
}
RETURN movie

The first part of the query finds the movie with the longest running time from cineasts.latest, and returns its release month. The second part of the query finds all movies in cineasts.upcoming that fulfill your condition and returns them. The sub-query imports the monthOfLongest variable using WITH monthOfLongest, to make it accessible.

Updates

Composite database queries can perform updates to constituent graphs.

Example 8. Constituent graph update

USE cineasts.upcoming
CREATE (:Movie {title: 'Dune: Part Two'})

Updates can only be performed on a single constituent graph per transaction.

Example 9. Multi-graph update will fail

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  CREATE (:Movie {title: 'The Flash'})
}

Writing to more than one database per transaction is not allowed.

Limitations

Queries on Composite databases have a few limitations.

Graph accessing operations

Consider a Composite database query:

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie

Here the outer clauses, i.e. the UNWIND, the CALL itself, and the final RETURN, appear in the root scope of the query, without a specifically chosen graph. Clauses or expressions in scopes where no graph has been specified must not be graph-accessing.

The following Composite database query is invalid because [p=(movie)-→() | p] AS paths is a graph-accessing operation in the root scope of the query:

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN [p=(movie)-->() | p] AS paths

See examples of graph-accessing operations:

RETURN 1 + 2 AS number
WITH node.property AS val

Nested `USE` clauses

An inner scope must use the same graph as its outer scope:

USE cineasts.latest
MATCH (n)
CALL {
  USE cineasts.upcoming
  MATCH (m)
  RETURN m
}
RETURN n, m

Nested subqueries must use the same graph as their parent query.
Attempted to access graph cineasts.upcoming
"    USE cineasts.upcoming"
     ^

Sub-queries without a USE clause can be nested. They inherit the specified graph from the outer scope.

CALL {
  USE cineasts.upcoming
  CALL {
    MATCH (m:Movie)
    RETURN m
  }
  RETURN m
}
RETURN m

Cypher runtime

When a query is submitted to a Composite database, different parts of the query may run using different runtimes. Clauses or expressions in scopes where no graph has been specified run using the slotted runtime. Parts of the query directed to different constituent graphs are run using the default runtime for that graph, or respect the submitted Cypher query options if specified.

Built-in graph functions

Graph functions are located in the namespace graph. The following table describes these functions:

Table 1. Built-in graph functions
Function	Explanation
`graph.names()`	Provides a list of names of all constituent graphs on the current Composite database.
`graph.byName(graphName)`	Used with the `USE` clause to select a constituent graph by name dynamically. This function is supported only with `USE` clauses.
`graph.propertiesByName(graphName)`	Returns a map containing the properties associated with the given graph.

For more information, see Graph functions in the Cypher Manual.

Glossary

allocator: A component in the cluster that allocates databases to servers according to the topology constraints specified and an allocation strategy.
asynchronous replication: Asynchronous replication is used by secondary copies to poll for new transactions, which means they cannot be guaranteed to have received the most recent transactions. This enables efficient scale-out of read-performance.
Aura instance: A fully-managed DBMS represented by a single instance ID, that is running in the Neo4j Aura cloud.
auto-commit transaction: An automatically committed transaction that contains a single query.
Bolt protocol: Bolt is a protocol used for interaction between Neo4j instances and drivers.
bookmark: A marker the client can request from the cluster to ensure that it is able to read its own writes so that the application’s state is consistent and only databases that have a copy of the bookmark are permitted to respond.
category (Bloom): A category is based on a node label and is defined in a Perspective as a way of visually distinguishing nodes with the same label(s).
causal consistency: All servers in a cluster agree on the order in which transactions take place. The position of a server on the causal chain can be guaranteed using a bookmark.
cluster: A Neo4j DBMS that spans multiple servers working together to increase fault tolerance and/or read scalability. Databases on a cluster may be configured to replicate across servers in the cluster thus achieving read scalability or high availability.
client application: Software that interacts with a Neo4j server.
commit: A commit is the successful completion of a transaction, which ensures durability of any changes made. For more details, visit Operations Manual → Transaction management.
composite database: Composite databases are the means to access partitioned graph data with a single Cypher query.
constraint: Constraints are sets of data modeling rules that ensure the data is consistent and reliable.
Cypher®: Neo4j’s graph query language.
data model: A data model defines how information is organized in a database. A good data model will make querying and understanding your data easier. In Neo4j, the data models have a graph structure.
database: A database is a container used by the DBMS to manage and store graph data. The physical structure of data is controlled by the database.
database vs graph: Databases are the physical containers of graph data. Graphs are the logical structure of data in Neo4j.
Database Management System: Database Management System, or DBMS, capable of managing multiple databases. A DBMS may run on a single server, or span several servers configured as a cluster.
database schema: The prescribed property existence and datatypes for nodes and relationships.
deallocate: An act of removing a database from a server or a server from a cluster without loss of data or reduced fault tolerance.
degree (of a node): The number of relationships of a specific node; loops are counted twice.
disaster recovery: A manual intervention to restore availability of a cluster, or databases within a cluster.
driver: A software library that provides access to Neo4j from a particular programming language.
election: In the event that the Raft leader becomes unresponsive, followers automatically trigger an election and vote for a new leader.
entity: A node or a relationship.
expression (Cypher): A component of a Cypher query which produces values. It may be used in projections, as a predicate, or when setting properties on graph elements.
fabric: Fabric is the architectural design of a unified system that provides a single access point to local or distributed graph data.
fault tolerance: A guarantee that a cluster can maintain a database’s persistence and availability in the event of one or more servers failing.
follower: A primary copy of a database acting as a follower, receives and acknowledges synchronous writes from the leader.
Generative AI (GenAI): A type of artificial intelligence (AI) system that generates text, images, or other media in response to prompts.
graph: A logical representation of a set of nodes where some pairs are connected by relationships.
index: Data structure that improves read performance of a database.
knowledge graph: A specific type of graph that has an organizing principle so that a user (or a computer system) can reason about the underlying data. The organizing principle provides an additional layer of structure that adds context to support knowledge discovery.
label: Marks a node as a member of a named and indexed subset. A node may be assigned zero or more labels.
leader: A single primary copy of a database is designated as the leader. It receives all write transactions from clients and replicates writes synchronously to followers and asynchronously to secondary copies of the database.
main database: In terms of Neo4j Enterprise Studio, the database(s) containing the user’s data. Can exist in the same Neo4j deployment as the tool asset database.
motif: A description of a specific pattern within a graph.
node: A node represents an entity or discrete object in your graph data model. Nodes can be connected by relationships, hold data in properties, and are classified by labels.
operator: A symbol representing a mathematical or logical operation.
parameter: Named value provided when running a Cypher statement.
path: A sequence of nodes and the relationships connecting them, that does not contain duplicate relationships. Several paths can match a pattern.
pattern: A specific arrangement of nodes and relationships that can be matched in a graph. A pattern follows a motif.
perspective (Bloom): A Perspective defines a certain business view or domain that can be found in the target Neo4j graph. A single Neo4j graph can be viewed through different Perspectives, each tailored for a different business purpose.
primary: A copy of the database that is able to process write transactions and is eligible to be elected as a leader. It participates in fault tolerant writes as it is part of the majority required to acknowledge and commit write transactions.
primary vs secondary: In a cluster, databases can operate in either primary or secondary mode. Primary databases are able to process write and read transactions, ensuring fault tolerance. Secondary databases are replicated asynchronously from primaries, and their main purpose is to provide read scaling within the cluster.
project (Aura): An isolated environment in the unified Aura console that contains its own database instances, configurations, and resources. Preceded by tenant in the classic Aura console.
property: Properties are key-value pairs that are used for storing data on nodes and relationships.
query (Cypher): A statement that retrieves or writes information to a database.
Raft group: A group of servers that are participating in hosting a particular database in primary mode.
Raft group member: A server that is participating in a Raft group. A server can be a member of one or more groups.
Raft log: A shared log between all Raft group members that is guaranteed to be consistently updated and viewed by those members. The log contains both database data and operational state of the Raft group.
Raft protocol: The networking mechanism that enables a database to replicate its data across multiple servers to give high availability for accessing the data and high durability to the data stored.
read scaling: Distributing query load by creating additional database copies hosted in secondary mode (read-only).
relationship: A relationship represents a connection between nodes in your graph data model. Relationships connect a source node to a target node, hold data in properties, and are classified by type.
secondary: An asynchronously replicated copy of the database that provides read scaling within the cluster.
seed: A seed is a database dump or a full backup used to create a database on a cluster. This is sometimes called seeding.
server: A physical machine, a virtual machine, or a container running an instance of Neo4j. Servers can be standalone or part of a cluster.
session: A causally linked sequence of transactions.
session consistency: An alternative name for Neo4j’s causal consistency.
standalone: A single server running Neo4j and not part of a cluster.
synchronous replication: Synchronous replication requires the leader primary to replicate a transaction and block the commit until a quorum of the follower primaries acknowledges that the transaction is successfully replicated. Once the transaction is replicated, the commit is allowed to proceed. This ensures data durability and consistency within the cluster.
system database: A database used by Neo4j to store system information.
tenant (Aura): An isolated environment in the classic Aura console that contains its own database instances, configurations, and resources. Replaced by project in the unified Aura console.
tool asset database: In terms of Neo4j Enterprise Studio, the database where tools' assets are stored. This can be in the same Neo4j deployment as the main database(s) or in a separate deployment.
topology: A configuration that describes how the copies of a database should be spread across the servers in a cluster, see primary mode and secondary mode.
transaction: A transaction comprises a unit of work performed against a database. It is treated in a coherent and reliable way, independent of other transactions. Transactions comply with the ACID consistency model (atomic, consistent, isolated, and durable).

Set up and query composite databasesEnterprise EditionNot available on Aura